XML-баннер



1. Карточка баннера

Описание:
подгружаемый XML-файл с баннером.
Тип кода:
XML.
Подробнее:
баннер представляет собой XML-файл, который AdRiver формирует в ответ на запрос баннера. В этом XML-файле описаны все параметры рекламного места, согласно которым видеоплеер или загрузчик рекламы в Flash-приложении отображает баннер. На рекламном месте в видеоплеере или загрузчике рекламы в Flash-приложении можно показывать следующие баннеры: flv, mp4 (видеоролики); swf, html, htm (flash-баннеры); gif, jpg, jpeg, png (графические баннеры).
Все файлы, кроме видеоролика, могут быть загружены в AdRiver либо размещены на стороннем сервере. Видеоролик может быть размещен только на стороннем сервере. Flash-ролик, картинка или flv-ролик обязательны. XML-баннер может также использоваться для сайтов, полностью сделанных по технологии Flash.

Примечание: Обращаем ваше внимание на то, что при размещении рекламы в видеоплеере через AdRiver необходима модификация исходного кода плеера. Модификация исходного кода должна осуществляться с ведома и при участии разработчика видеоплеера. При использовании коммерческих видеоплееров на стороне площадки, AdRiver выступает в качестве третьего лица, и не может вносить какие-либо изменения в коды коммерческих плееров, а также оказывать консультации по работе коммерческих программных продуктов сторонних производителей.

2. Загрузка баннера и получение кода

2.1. Загрузка баннера

  1. Добавьте баннер типа xml баннер (special—>> xml banner—>> xml banner).
  2. Кликните по ссылке загрузить баннер и загрузите файлы для баннера. Flash-ролик и графические файлы могут быть загружены в AdRiver или размещены на стороннем сервере. Flv- и mp4-ролики могут быть размещёны только через поле location.
  3. При необходимости, впишите ссылки на сторонние пиксели.

2.2. Получение кода

  1. Сгенерируйте код для баннера

    Общий код сайта для издателей

    <!--  AdRiver code START. Type:xml banner Site: example PZ: 0 BN: 0 -->
    Ролик:http://ad.adriver.ru/cgi-bin/erle.cgi?sid=94499&target=top&bt=54&pz=0&rnd=1734737595
    Клик:http://ad.adriver.ru/cgi-bin/click.cgi?sid=94499&bt=54&pz=0&rnd=1734737595<!--  AdRiver code END  -->
    

    Код баннера для агентств

    <!-- AdRiver code START: код для баннера; AD: 217104 "XML-video";   сценарий   ID 417286 "XML-video"  баннер ID 775141; xml banner -->
    Ролик:http://ad.adriver.ru/cgi-bin/erle.cgi?sid=1&ad=217104&bt=54&pid=417286&bid=775141&bn=775141&rnd=1426200797
    Клик:http://ad.adriver.ru/cgi-bin/click.cgi?sid=1&ad=217104&bt=54&pid=417286&bid=775141&bn=775141&rnd=1426200797
    <!-- AdRiver code END -->
    
  2. Вам понадобится часть кода Ролик. Отредактируйте его, удалив случайное число и заменив его на ![rnd]. Тогда оно будет автоматически заменяться на сгенерированное случайное число. Пример:
    Ролик:http://ad.adriver.ru/cgi-bin/erle.cgi?sid=94499&target=top&bt=54&pz=0&rnd=
    

    Отредактированный код:

    Ролик:http://ad.adriver.ru/cgi-bin/erle.cgi?sid=94499&target=top&bt=54&pz=0&rnd=![rnd]
    
  3. Эту ссылку вставьте в видеоплеер или загрузчик рекламы в Flash-приложении.

2.3. Загрузка в баннер произвольного XML-файла

Стандартный XML-файл AdRiver отдаёт следующую информацию:

  • ссылка на картинку (если загружена)
  • ссылка на flash- ролик (если загружен)
  • ссылка на видео (если указана)
  • два сторонних счётчика

Стандартная библиотека имеет встроенные функции для клика и вызова событий.

Если вам нужен индивидуальный набор параметров, вы можете загрузить произвольный XML-файл в AdRiver.

Загрузить произвольный XML-файл можно, добавив баннер generic XML и загрузив собственный файл index.xml, а также, при необходимости, flv(mp4)-файлы/swf-файлы/графические файлы.

Для типа баннера generic XML подходят стандартные библиотеки adriver.xml.as для ActionScript 2 и getObjectFromXML для ActionScript 3. При использовании стандартных библиотек, XML-контент из баннера доступен в свойстве o.xml.

3. Подготовка видеоплеера или загрузчика рекламы в Flash-приложении

3.1. Видеоплеер/загрузчик рекламы в Flash-приложении на ActionScript 2

Скачайте пример исходников и библиотеку adriver.xml.as. Сохраните в одну папку файл adriver.xml.as и исходники видеоплеера или загрузчика рекламы в Flash-приложении.

В вашем видеоплеере пропишите следующий скрипт:

#include "adriver.xml.as"

Stage.scaleMode = "noScale";
Stage.align = 'TL';
btn._visible = false;

var conn = new NetConnection();
conn.connect(null);
var stream = new NetStream(conn);
vid.attachVideo(stream);

function onXMLLoad(o){
    btn.onRelease = function(){
        o.makeClick();
    }

    o.sendPixel(o.pixel1);
    o.sendPixel(o.pixel2);

    if (o.flv){
        stream.play(o.flv);

        btn._visible = true;
    }
    else if (o.swf){
        var mcLoader = new MovieClipLoader();
        mcLoader.addListener({onLoadInit:function (mc:MovieClip){
            mc._lockroot = true;
        }});
        mcLoader.loadClip(o.swf + '?link1=' + escape(o.ar_cgihref), mov);
    }
    else if (o.image){
        var mcLoader = new MovieClipLoader();
        mcLoader.addListener({onLoadInit:function (mc:MovieClip){
            btn._visible = true;
        }});
        mcLoader.loadClip(o.image, mov);
    }
    else{
        trace('пришла системная заглушка AdRiver');
    }
}

new getObjectFromXML("http://ad.adriver.ru/cgi-bin/erle.cgi?sid=94499&target=top&bt=54&pz=0&rnd=![rnd]", onXMLLoad);
  1. Замените ссылку, указываемую при создании объекта getObjectFromXML в строке 44 на вашу собственную ссылку из п. 2.2.
  2. Вы можете выполнить какую-либо команду в том случае, если пришла системная заглушка AdRiver.

Описание:

getObjectFromXML
функция, вызываемая для показа баннера. Первый параметр — ссылка на вызов баннера, второй параметр — ссылка на функцию onXMLLoad
onXMLLoad(o)
функция, которая выполняется после полной загрузки XML-файла. Аргумент функции (в данном примере он называется о, разработчик плеера или приложения может выбрать другое название) — это объект с необходимым набором функций для клика, вызова события, со ссылками на местоположение файлов, сторонние пиксели
o.makeClick()
функция, которая вызывается для выполнения клика по баннеру (в примере данная функция прописывается на кнопку btn). При необходимости, можно указать альтернативный URL в видеоплеере/приложении. Пример:
o.makeClick('альтернативный URL, должен начинаться с http://')
o.sendPixel()
функция, которая используется для вызова стороннего счётчика (o.pixel1 — ссылка на первый счётчик, o.pixel2 — ссылка на второй счётчик; задаются в соответствующих полях в интерфейсе при загрузке баннера). В примере вызываются оба пикселя. Если ни один пиксель не указан, то функция o.sendPixel ничего не вызывает

В зависимости от того, какие файлы загружены в баннер, их можно подгрузить и отобразить (o.swf — ссылка на flash-ролик, o.image — ссылка на изображение, o.flv — ссылка на видеоролик формата flv или mp4). В примере проверяется, есть ли в баннере видеоролик и если файл найден, то он подгружается, если нет, проверяется, есть ли в баннере flash-ролик или изображение и если файл найден, то он подгружается. Как только файл загружен, он масштабируется, а также отображается скрытая ранее кнопка для клика (функция onLoadInit).

В XML-баннере можно учитывать отдельные действия (например, показы и клики по дополнительным блокам, картинкам, Flash-роликам) событиями.

Функция o.sendEvent может вызываться в видеоплеере или загрузчике рекламы в flash-приложении для учёта событий. Принимает в качестве параметра число. Доступны события от 1 до 9, событие 0 вызывается автоматически, как только полностью загружен XML-файл.

Значения событий с 1 до 9 вы можете отдать под свои метрики. Рекомендуем раскладку событий в видеоплеерах, которая частично соответствует спецификациям IAB VAST 2.0.

  • событие 0 — начало просмотра. Событие должно вызываться в момент, когда началось действительное воспроизведение ролика, после завершения его буферизации.
  • событие 1 — первая четверть ролика
  • событие 2 — середина просмотра
  • событие 3 — третья четверть ролика
  • событие 4 — окончание просмотра
  • событие 5 — выключение звука
  • событие 6 — включение звука
  • событие 7 — любое разворачивание рекламы (больше своего первоначального размера)
  • событие 8 — любое сворачивание рекламы (меньше своего первоначального размера)
  • событие 9 — пропуск рекламы (закрытие кнопкой пропустить, крестиком или иным аналогичным действием)

В нужные места в плейере/загрузчике рекламы в flash-приложении пропишите вызов соответствующих событий:

  • o.sendEvent (1)
  • o.sendEvent (2)
  • o.sendEvent (9).

Для баннеров после установки этих функций в плейере/загрузчике рекламы в Flash-приложении можно назначенные события считать автоматически.

Параметры, которые могут использоваться в видеоплеере/загрузчике рекламы в Flash-приложении:

o.image
ссылка на изображение
o.swf
ссылка на flash-ролик
o.flv
ссылка на видеоролик
o.pixel1
ссылка на первый счётчик
o.pixel2
ссылка на второй счётчик
o.sendEvent
функция для учёта события (event). Принимает в качестве параметра число. Доступны события от 1 до 9, событие 0 вызывается автоматически, как только полностью загружен XML-файл
o.sendPixel
функция для вызова счётчика. Принимает в качестве параметра ссылку (строку)
o.makeClick
функция для клика. Может принимать URL в качестве параметра: o.makeClick(‘URL для альтернативного перехода’)

3.2. Видеоплеер/загрузчик рекламы в Flash-приложении на ActionScript 3

Скачайте пример исходников и библиотеку getObjectFromXML. Сохраните в одну папку исходники видеоплеера/загрузчика рекламы в Flash-приложении и папку с названием adriver, содержащую файл getObjectFromXML.

В вашем видеоплеере пропишите следующий код:

import adriver.getObjectFromXML;
import flash.net.NetConnection;
import flash.net.NetStream;

btn.enabled = false;
btn.x = -1000;

var conn = new NetConnection();
conn.connect(null);
var stream = new NetStream(conn);
vid.attachNetStream(stream)

function onXMLLoad(o){
    btn.addEventListener(MouseEvent.CLICK, function(e){
        o.makeClick();
    });

    o.sendPixel(o.pixel1);
    o.sendPixel(o.pixel2);

    if (o.flv) {
        stream.play(o.flv);

        btn.enabled = true;
        btn.x = 0;
    }
    else if (o.swf) {
        var l:Loader = new Loader();
        l.load(new URLRequest(o.swf + '?link1=' + escape(o.ar_cgihref)));
        mov.addChild(l);
    }
    else if (o.image) {
        var loader:Loader = new Loader();
        loader.contentLoaderInfo.addEventListener(Event.INIT, function(e){
            btn.enabled = true;
            btn.x = 0;
        });
        var request:URLRequest = new URLRequest(o.image);
        loader.load(request);
        mov.addChild(loader);
    }
    else {
        trace('пришла системная заглушка AdRiver')
    }
}

new getObjectFromXML("http://ad.adriver.ru/cgi-bin/erle.cgi?sid=94499&target=top&bt=54&pz=0&rnd=![rnd]", onXMLLoad); 
  1. Замените ссылку, указываемую при создании объекта getObjectFromXML в строке 47 на вашу собственную ссылку из п.2.2.
  2. Вы можете выполнить какую-либо команду в том случае, если пришла системная заглушка AdRiver.